// ################################
// ### Ultima Alianza 2001-2014 ###
// ################################

[ITEMDEF i_decay_barco]
ID=0108a
NAME=Temporizador Decay Barco
TYPE=t_eq_script
WEIGHT=0

ON=@CREATE
ATTR=attr_invis|attr_move_never|attr_decay
TIMER=60

ON=@TIMER
IF ((<LINK.CONT> > 0) || !(<TAG0.DBASEID>==<LINK.BASEID>))
	LINK=04fffffff
	REMOVE
	RETURN 1
ELSE
	IF (<LINK.REGION.FLAGS>&region_flag_ship)
		IF (<TAG0.DBASEID>==<LINK.BASEID>)
			LINK.REMOVE
		ENDIF
	ENDIF
	LINK=04fffffff
	REMOVE
	RETURN 1
ENDIF

[DIALOG d_barco]
0, 0
SRC.DIALOGCLOSE d_barco
NOCLOSE
PAGE 0
RESIZEPIC 0 0 2620 250 350
PAGE 1
button 210 315 4017 4018 1 0 0
button 100 40 4500 4500 1 0 1
button 170 40 4501 4501 1 0 2
button 170 100 4502 4502 1 0 3
button 170 160 4503 4503 1 0 4
button 100 160 4504 4504 1 0 5
button 30 160 4505 4505 1 0 6
button 30 100 4506 4506 1 0 7
button 30 40 4507 4507 1 0 8
button 110 114 4020 4020 1 0 9
button 20 240 4005 4006 1 0 10
button 20 270 4005 4006 1 0 11
button 20 300 4005 4006 1 0 12
text 65 240 1152 0
text 65 270 1152 1
text 65 300 1152 2
text 48 9 1152 3

[DIALOG d_barco TEXT]
Girar.
Elevar Ancla.
Soltar Ancla.
Sistema de Navegacion.

[DIALOG d_barco BUTTON]
on=0
SRC.TAG.UIDBARCO=
SRC.SYSMESSAGE @0 Has cerrado el sistema de navegacion...

on=1
SRC.SAY Adelante!
IF (<SRC.FINDID.i_on_boat.TAG.ACELERACION>==0)
	SRC.FINDID.i_on_boat.TAG.ACELERACION=1
	SERV.NEWITEM i_shiphaste 
	NEW.LINK=<SRC.FINDID.i_on_boat.UID> 
	NEW.NAME=Control de velocidad <NAME> 
	NEW.ATTR=attr_invis|attr_move_never 
	NEW.P=<P> 
	NEW.TIMER=1 
ENDIF
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ADELANTE
SRC.DIALOG d_barco

on=2
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ADELANTEDER
SRC.DIALOG d_barco

on=3
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_DERECHA
SRC.DIALOG d_barco

on=4
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ATRASDER
SRC.DIALOG d_barco

on=5
SRC.SAY Atras!
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ATRAS
SRC.DIALOG d_barco

on=6
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ATRASIZQ
SRC.DIALOG d_barco

on=7
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_IZQUIERDA
SRC.DIALOG d_barco

on=8
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ADELANTEIZQ
SRC.DIALOG d_barco

on=9
SRC.SAY Para!
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_PARAR
SRC.DIALOG d_barco

on=10
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_GDERECHA
SRC.DIALOG d_barco

on=11
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_LEVARANCLAS
SRC.DIALOG d_barco

on=12
TRY UID.<SRC.TAG0.UIDBARCO>.NAVEGACION_ANCLAR
SRC.DIALOG d_barco

// ################################
// ################################
// ################################

[ITEMDEF i_on_boat]
NAME=On Boat
ID=014f1
TYPE=t_eq_script
WEIGHT=0
LAYER=layer_special

ON=@CREATE
ATTR=attr_Invis|attr_decay
TAG.ACELERACION=0

ON=@EQUIP
LINK=<SRC.REGION.UID>
LINK.TAG0.PASAJEROS=<LINK.TAG0.PASAJEROS>+1
LINK.LINK.SAY @0481 Pasajeros: <dLINK.TAG0.PASAJEROS>

On=@UNEQUIP
LINK.TAG0.PASAJEROS=<LINK.TAG0.PASAJEROS>-1
LINK.LINK.SAY @0481 Pasajeros: <dLINK.TAG0.PASAJEROS>

ON=@TIMER
RETURN 1

[ITEMDEF i_shiphaste] 
ID=01ea7 
TYPE=t_eq_script 
NAME=Ship Speed Control 

ON=@Timer 
IF (<LINK.BASEID>==i_on_boat)
	IF !(<LINK.LINK.TIMER>==-1)
		TIMERD=3
		LINK.LINK.TIMERD=1
	ELSE
		LINK.TAG.ACELERACION=0
		REMOVE
	ENDIF
ELSE
	REMOVE 
ENDIF
RETURN 1 

[ITEMDEF I_BOAT_TIMER]
NAME=Boat Redeed Timer
ID=014f1
TYPE=t_eq_script
WEIGHT=0
LAYER=layer_special

ON=@CREATE
ATTR=attr_invis|attr_decay
TAG.CUENTAATRAS=10

ON=@EQUIP
TIMER=1
LINK=<SRC.REGION.UID>
IF <LINK.BASEID>==i_multi_ship_small_N
	TAG.XBASEID=i_deed_ship_small_N
ELSEIF <Link.BaseID>==i_multi_ship_dragon_small_N
	TAG.XBASEID=i_deed_ship_dragon_small_N
ELSEIF <Link.BaseID>==i_multi_ship_medium_N
	TAG.XBASEID=i_deed_ship_medium_N
ELSEIF <Link.BaseID>==i_multi_ship_dragon_medium_N
	TAG.XBASEID=i_deed_ship_dragon_medium_N
ELSEIF <Link.BaseID>==i_multi_ship_long_N
	TAG.XBASEID=i_deed_ship_long_N
ELSEIF <Link.BaseID>==i_multi_ship_dragon_long_N
	TAG.XBASEID=i_deed_ship_dragon_long_N
ELSEIF <Link.BaseID>==i_multi_skiff_n
	TAG.XBASEID=i_deed_multi_skiff_n
ENDIF
SRC.SAY @0 El barco se convertira en escritura en <dTAG0.CUENTAATRAS>> segundos.
SRC.SAY @0481 Salid todos del barco!

ON=@TIMER
IF (<CONT>)
	IF (<TAG0.CUENTAATRAS>)
		CONT.MESSAGE <EVAL <TAG.CUENTAATRAS>>
		TAG.CUENTAATRAS=<TAG.CUENTAATRAS>+-1
		TIMER=1
		RETURN 1
	ENDIF
ENDIF
REMOVE
RETURN 1

ON=@UNEQUIP
IF <LINK.TAG0.PASAJEROS>>0
	SRC.SYSMESSAGE @0 No debe haber nadie en el barco!
ELSE
	IF <TAG0.XBASEID>
		LINK.REMOVE
		SERV.NEWITEM=<TAG.XBASEID>
		NEW.BOUNCE
		SRC.RESEND
		SRC.SYSMESSAGE @0 Barco convertido en escritura.
	ELSE
		SRC.SYSMESSAGE @0 Tienes que poner el barco recto para convertirlo en escritura.
		SRC.SYSMESSAGE @0 Si aun asi no puedes ha habido algun fallo. Avisa a un GM.
	ENDIF
ENDIF

[ITEMDEF 03e84]
//gang plank
TYPE=T_SHIP_PLANK
TDATA1=03e85

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

CATEGORY=Ship Parts
SUBSECTION=Gang Plank
DESCRIPTION=@
//DUPELIST=03e86,03e89,03ed3,03ed4,03ed5

[ITEMDEF 03e85]
//ship
NAME=barco
TYPE=T_SHIP_SIDE_LOCKED
TDATA1=03e84

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03e86]
//gang plank
TYPE=T_SHIP_PLANK
TDATA1=03e87

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03e87]
//ship
NAME=barco
TYPE=T_SHIP_SIDE_LOCKED
TDATA1=03e86

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03ed3]
//gang plank
TYPE=T_SHIP_PLANK
TDATA1=03ea9

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
return 0

[ITEMDEF 03ea9]
//ship
NAME=barco
TYPE=T_SHIP_SIDE_LOCKED
TDATA1=03ed3

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03ed4]
//gang plank
TYPE=T_SHIP_PLANK
TDATA1=03eb2

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03eb2]
//ship
NAME=barco
TYPE=T_SHIP_SIDE_LOCKED
TDATA1=03ed4

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03ed5]
//gang plank
TYPE=T_SHIP_PLANK
TDATA1=03eb1

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

[ITEMDEF 03eb1]
//ship
NAME=barco
TYPE=T_SHIP_SIDE_LOCKED
TDATA1=03ed5

ON=@DCLICK
LINK.REGION.EVENTS +r_ship
RETURN 0

//End Modified Ship Planks
//Begin Boat Menu

[MENU M_BOAT_Main]
Menu del Barco - Pasajeros: <QVAL (<TARG.TYPE>==t_ship_tiller) ? <dTARG.LINK.TAG0.PASAJEROS> : <dTARG.TAG0.PASAJEROS>>
On=0 Convertir el barco en escritura
SRC.MENU M_BOAT_DEED

[MENU M_BOAT_DEED]
Menu del Barco - Confirmacion.
On=0 Si quiero seguir. NOTA: Todos los objetos del barco se perderan y hay una diminuta posibilidad de que el barco desaparezca si te alejas. No devolveremos los barcos que se pierdan de esta manera. 
REF1=<SRC.REGION.UID>
If (<REF1.BASEID>==i_multi_ship_small_n) || (<REF1.BASEID>==i_multi_ship_dragon_small_n) || (<REF1.BASEID>==i_multi_ship_medium_n) || (<REF1.BASEID>==i_multi_ship_dragon_medium_n) || (<REF1.BASEID>==i_multi_ship_long_n) || (<REF1.BASEID>==i_multi_ship_dragon_long_n) || (<REF1.BASEID>==i_multi_skiff_n) 
	IF !(<SRC.FINDID.I_BOAT_TIMER>)
		SRC.NEWITEM I_BOAT_TIMER
		SRC.ACT.EQUIP
	ENDIF
ELSE
	SRC.SYSMESSAGE @0 Debes colocar el barco en orientacion Norte-Sur para poder convertirlo en escritura.
ENDIF
RETURN 1


On=0 No quiero seguir. Volver al menu anterior.
Menu M_BOAT_Main

[EVENTS E_ON_BOAT]

ON=@ITEMCREATE
IF (<ARGO.TYPE>==t_fish)
	IF (<REGION.FLAGS>&region_flag_ship)
		SYSMESSAGE @086 Cualquier cosa que pongas sobre el barco desaparecera en 60 segundos!
		SYSMESSAGE @0 Para guardar cosas usa la trampilla.
		LOCAL.DUID=<ARGO.UID>
		LOCAL.P=<ARGO.P>
		LOCAL.DBASEID=<ARGO.BASEID>
		SERV.NEWITEM=i_decay_barco
		NEW.LINK=<LOCAL.DUID>
		NEW.TAG.DBASEID=<LOCAL.DBASEID>
		NEW.TAG.P=<LOCAL.P>
		NEW.P=<SRC.P>
		NEW.TIMER=60
	ENDIF
ENDIF

ON=@itemDROPON_GROUND
IF (<SRC.REGION.FLAGS>&region_flag_ship)
	IF (<SRC.ACT.REGION.FLAGS>&region_flag_ship)
		SRC.SYSMESSAGE @086 Cualquier cosa que pongas sobre el barco desaparecera en 60 segundos!
		SRC.SYSMESSAGE @0 Para guardar cosas usa la trampilla.
		LOCAL.DUID=<SRC.ACT.UID>
		LOCAL.P=<SRC.ACT.P>
		LOCAL.DBASEID=<SRC.ACT.BASEID>
		SERV.NEWITEM=i_decay_barco
		NEW.LINK=<LOCAL.DUID>
		NEW.TAG.DBASEID=<LOCAL.DBASEID>
		NEW.TAG.P=<LOCAL.P>
		NEW.P=<SRC.P>
		NEW.TIMER=60
	ENDIF
ENDIF
	

ON=@itemDCLICK
IF (<SRC.IsGM>)&&(<ACT.TYPE>=t_ship_tiller)
	SRC.MENU M_BOAT_MAIN
	RETURN 1
ELSEIF (<ACT.TYPE>==t_ship)&&(<ACT.MORE1>==<SRC>)&&(<SRC.REGION.UID>==<ACT.REGION.UID>)
	SRC.MENU M_BOAT_MAIN
	RETURN 1
ELSEIF (<ACT.TYPE>=t_ship_tiller)&&(<UID.<ACT.MORE1>.MORE1>==<SRC>)&&(<SRC.REGION.UID>==<ACT.REGION.UID>)
	SRC.MENU M_BOAT_MAIN 
	RETURN 1
ELSE
	RETURN 0
ENDIF

// ##########################################################
// ################## FUNCIONES DE NAVEGACION ###############
// ##########################################################

[FUNCTION NAVEGACION_ADELANTE]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPFORE
ELSE
	SHIPDRIFTLEFT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ATRAS]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPBACK
ELSE
	SHIPDRIFTRIGHT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_PARAR]
SHIPSTOP
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_GIZQUIERDA]
//LOCAL.TMP=<OBJ>
//OBJ=<UID>
//FORITEMS 8
//	IF (<TYPE>==t_ship)
//		IF (<UID>!=<OBJ>)
//			SRC.SYSMESSAGE @0 Hay un barco cerca, no puedes girar.
//			return 1
//		ENDIF
//	ENDIF
//ENDFOR
//OBJ.SHIPTURNLEFT
//OBJ.SHIPFIX
//OBJ=<LOCAL.TMP>
SHIPTURNLEFT
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_GDERECHA]
//LOCAL.TMP=<OBJ>
//OBJ=<UID>
//FORITEMS 8
//	IF (<TYPE>==t_ship)
//		IF (<UID>!=<OBJ>)
//			SRC.SYSMESSAGE @0 Hay un barco cerca, no puedes girar.
//			return 1
//		ENDIF
//	ENDIF
//ENDFOR
//OBJ.SHIPTURNRIGHT
//OBJ.SHIPFIX
//OBJ=<LOCAL.TMP>
SHIPTURNRIGHT
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_IZQUIERDA]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPDRIFTLEFT
ELSE
	SHIPBACK
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_DERECHA]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPDRIFTRIGHT
ELSE
	SHIPFORE
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ADELANTEIZQ]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPFORELEFT
ELSE
	SHIPBACKLEFT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ADELANTEDER]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPFORERIGHT
ELSE
	SHIPFORELEFT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ATRASIZQ]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPBACKLEFT
ELSE
	SHIPBACKRIGHT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ATRASDER]
IF !(strmatch("i_multi_skiff*","<baseid>"))
	SHIPBACKRIGHT
ELSE
	SHIPFORERIGHT
ENDIF
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_LEVARANCLAS]
SHIPANCHORRAISE
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ANCLAR]
SHIPANCHORDROP
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_MEDIAVUELTA]
SHIPTURN
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ARRIBA]
SHIPUP
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ABAJO]
SHIPDOWN
ACTUALIZAR_BARCO

[FUNCTION NAVEGACION_ATRACAR]
SHIPLAND
ACTUALIZAR_BARCO

[FUNCTION ACTUALIZAR_BARCO]
IF (strmatch(*Barco*,"<LINK.REGION.NAME>"))
	LINK.REGION.EVENTS +r_ship
ENDIF
LINK.TIMER=259200
LINK.ATTR=04002

// ############################################################
// ###################### SPEECH DE BARCOS ####################
// ############################################################

[SPEECH spk_ship_cmds]

ON=Navegacion
IF (<MORE>==<SRC.SERIAL>)||(<SRC.isGM>)
	SRC.DIALOG d_barco
	SRC.TAG.UIDBARCO=<UID>
	ACTUALIZAR_BARCO
ELSE
	SRC.SYSMESSAGE @0 Solo el capitan del barco puede usar el menu de navegacion!
ENDIF

ON=Furl sail   // Stop
ON=Stop    // Stops current ship movement.
ON=Para
ON=parar
ON=detente
NAVEGACION_PARAR
	
ON=Turn Left
ON=Port    // Turn Left
ON=Girar izquierda
ON=gira izquierda
NAVEGACION_GIZQUIERDA

ON=Turn Right
ON=Starboard
ON=Girar derecha
ON=gira derecha
NAVEGACION_GDERECHA

ON=Left    // Move ship in desired direction.
ON=Drift Left
ON=Izquierda
ON=Babor
NAVEGACION_IZQUIERDA

ON=Right   // Move ship in desired direction.
ON=Drift Right
ON=Derecha
ON=Estribor
NAVEGACION_DERECHA

ON=Back    // Move ship backwards
ON=Backward   // Move ship backwards
ON=Backwards   // Move ship backwards
ON=Atras
ON=Retrocede
ON=Retroceder
NAVEGACION_ATRAS

ON=Forward
ON=Foreward   // Moves ship forward.
ON=Unfurl sail   // Moves ship forward.
ON=Adelante
NAVEGACION_ADELANTE

ON=Forward left
NAVEGACION_ADELANTEIZQ

ON=forward right
NAVEGACION_ADELANTEDER

ON=backward left
ON=back left
NAVEGACION_ATRASIZQ

ON=backward right
ON=back right
NAVEGACION_ATRASDER

ON=Raise Anchor
ON=Levar ancla
ON=Levar anclas
NAVEGACION_LEVARANCLAS

ON=Drop Anchor
ON=Tirar ancla
ON=Echar ancla
NAVEGACION_ANCLAR

ON=Media Vuelta
ON=Turn around   // Turns ship around and proceeds.
ON=Come about   // Turns ship around and proceeds.
NAVEGACION_MEDIAVUELTA

ON=Up
ON=arriba
NAVEGACION_ARRIBA

ON=Down
ON=abajo
NAVEGACION_ABAJO

ON=Land
ON=Atracar
NAVEGACION_ATRACAR

// ####################################################################
// ################## FUNCIONES DE NAVEGACION POR MAPAS ###############
// ####################################################################

[FUNCTION F_NAV_2]
src.act=0<REGION.TAG.TILLERMAN>
if 0<src.TARG>=0<src.ACT>
 src.act.say Detente!
elif <src.targ..type>!=t_map
 src.act.say Eso no es un mapa capitan!
elif <src.targ.more1l>><p.x>
 src.act.say Desconozco donde estamos capitan! Tal vez deberiamos trazar una ruta en el mapa del mundo!
elif <src.targ.more1h>><p.y>
 src.act.say Desconozco donde estamos capitan! Tal vez deberiamos trazar una ruta en el mapa del mundo!
elif <src.targ.more2l><<p.x>
 src.act.say Desconozco donde estamos capitan! Tal vez deberiamos trazar una ruta en el mapa del mundo!
elif <src.targ.more2h><<p.y>
 src.act.say Desconozco donde estamos capitan! Tal vez deberiamos trazar una ruta en el mapa del mundo!
else
 try var.morep <src.targ.morep>
 src.targ.get_map_p 1
 tag.mapx=<src.targ.morex>
 tag.mapy=<src.targ.morey>
 if (0<tag.mapx><1)|(0<tag.mapy><1)
  src.act.say No tengo ni la menor idea de donde esta esa ubicacion!
 else
  tag.pin=1
  tag.map=<src.TARG>
  src.act.say Si mi capitan! ruta fijada! Viento en popa a toda vela!
  if 0<tag.mapx>><p.x>
   shipturn
  shipfore
  more2=<eval <more2>+1>
  f_start_ship
 endif
endif

[FUNCTION F_NAV_CHAR]
src.act=0<REGION.TAG.TILLERMAN>
src.act.say No creo que eso sea un mapa capitan!

[function get_map_p]
morep=<pin.<args>>
var.num1=100
morex=<eval <more1h>+((<more2h>-<more1h>)/194)*<morex>))>
morey=<eval <more1l>+((<more2l>-<more1l>)/194)*<morey>))>

[function go_pin]
get_map_p <args>
src.go <morep>
src.fix
src.say <morep>

[function f_start_ship]
//src.say start
var.act=<src.ACT>
src.act=0<tag.shipwatch>
if 0<src.ACT>=0
src.newitem i_ship_watch
src.act.p=<p>
src.act.fix
src.act.link=<uid>
tag.shipwatch=<src.ACT>
src.act.timerd=1
endif
src.act=<var.act>
var.act

[itemdef i_ship_watch]
id=02007
type=t_eq_script
layer=30

on=@create
attr=attr_decay

on=@timer
timerd=1
if <link.p.x><5120
link.wrapx
endif
if <link.p.x><5120
link.wrapy
endif
if (<link.more2>&01)|(<link.more2>&02)
else
link.tag.shipwatch
remove
endif
return 1

[function wrapx]
if <p.x>>5100
shipgate 20,<p.y>
elif <p.x><20
shipgate 5100,<p.y>
endif

[function wrapy]
if <p.y>>4086
shipgate <p.x>,8,<mapplane>,<z>
elif <p.y><8
shipgate <p.x>,4086,<mapplane>,<z>
endif

[REGIONTYPE r_ship]
DEFNAME=r_ship

ON=@ENTER
SRC.SYSMESSAGE @086 AVISO:
SRC.SYSMESSAGE @0481 Di Navegacion para activar el sistema de navegacion. Tras 3 dias de desuso un barco es eliminado.
SRC.EVENTS +e_on_boat

ON=@STEP
IF !(<SRC.ISGM>)
	IF !(<SRC.RESTEST 1 i_on_boat>) && (<SRC.NPC>==0)
		SERV.NEWITEM i_on_boat
		NEW.EQUIP <SRC>
	ENDIF
ENDIF

ON=@EXIT
SRC.EVENTS -e_on_boat
IF (<SRC.FINDID.i_on_boat>)
	SRC.FINDID.i_on_boat.REMOVE
ENDIF

[EOF]